[tex-live] logfile format

[Werner LEMBERG]

>     Is it possible to first have the entry's log message in `svnlog', and
>     then the list of affected files?
> 
> Anything's possible.  I'm just taking the output from  svn log  as it
> comes.  It would be easy enough to split it at a blank line and
> transpose, well, except the first line should stay first.  Maybe you'd
> like to hack this?  Build/tools/svnchangelog ...

Here's a sed script which does what I want.


    Werner


======================================================================


#! /usr/bin/sed -nf

:main
/------------------------------------------------------------------------/ {
  p
  n
  /r[0-9][0-9]* / {
    p
    n
    /^Changed paths:$/ {
      h
      n

      :loop1
      /^$/! {
        H
        n
        bloop1
      }

      :loop2
      /------------------------------------------------------------------------/! {
        p
        n
        bloop2
      }

      i\

      x
      p
      g
      bmain
    }
  }
  bmain
}

p